Server Administration

From Zero to Complete IP Inventory in 5 Seconds: The Multi-Host VBScript | Lazy Admin Blog

Posted on Updated on

Manually documenting IP addresses, MACs, and DNS settings is the definition of “busy work.” This VBScript automates the entire process. It reads a list of servers from a text file, queries each one via WMI, and builds a professional Excel report in real-time.

How to Use This Script

  1. Prepare the Input: Create a text file (e.g., servers.txt) and list your hostnames or IP addresses, one per line.
  2. Save the Script: Save the code below as IPAddressInventory.vbs.
  3. Run: Double-click the .vbs file. When prompted, provide the full path to your text file (e.g., C:\Scripts\servers.txt).
  4. Requirement: You must have Microsoft Excel installed on the machine where you run the script.

The VBScript Code

VBScript

' Save as IPAddressInventory.vbs
' Input: Text file with Hostnames/IPs
' Output: Excel Spreadsheet (IP_Addresses.xlsx)
On Error Resume Next
Const FOR_READING = 1
'--- File Input ---
strSrvListFile = InputBox ("Please enter the server list file path OR UNC file path" & vbCrLf & "Eg: C:\Scripts\server.txt" & vbCrLf & "Eg: \\servername\scripts\server.txt","File Input location")
Set objFSO = CreateObject ("Scripting.FileSystemObject")
Set objReadFile = objFSO.OpenTextFile (strSrvListFile, FOR_READING)
'--- File Output ---
strOutput = objfso.GetParentFolderName(strSrvListFile) &"\"
'--- Error Handling ---
If Err.Number <> 0 Then
   WScript.Echo "Please Enter a Valid file Name"
   Err.Clear
   WScript.Quit
End If
'--- Excel Object Creation ---
Set objExcel = CreateObject ("Excel.application")
objExcel.Visible = True
Set objWorkbook = objExcel.Workbooks.Add()
Set objWorksheet = objWorkbook.Worksheets("Sheet1")
x = 1
y = 1
'--- Define Headers ---
objWorksheet.Cells (x, y).value = "S.No"
objWorksheet.Cells (x, y+1).value = "Server Name"
objWorksheet.Cells (x, y+2).value = "Description"
objWorksheet.Cells (x, y+3).value = "IP_Address"
objWorksheet.Cells (x, y+4).value = "Subnet"
objWorksheet.Cells (x, y+5).value = "MACAddress"
objWorksheet.Cells (x, y+6).value = "Gateway" 
objWorksheet.Cells (x, y+7).value = "Preffered DNS"
objWorksheet.Cells (x, y+8).value = "Primary DNS"
objWorksheet.Cells (x, y+9).value = "Secondary DNS"
objWorksheet.Cells (x, y+10).value = "Additional DNS 1"
objWorksheet.Cells (x, y+11).value = "Additional DNS 2"
objWorksheet.Cells (x, y+12).value = "WINS Primary"
objWorksheet.Cells (x, y+13).value = "WINS Secondary"
objWorksheet.Cells (x, y+14).value = "DNS Suffix"
objWorksheet.Cells (x, y+15).value = "DNS Suffix Order"
objWorksheet.Cells (x, y+16).value = "Remarks"
s = 1
Do Until objReadFile.AtEndOfStream
    k = 0
    arrComputer = objReadFile.ReadLine
    strServer = Split (arrComputer, ",")
    objWorksheet.Cells (x+1, y).value = s
    objWorksheet.Cells (x+1, y+1).value = strServer(k)
    Set objWMIService = GetObject ("winmgmts:" & "!\\" & strServer(k) & "\root\cimv2")
   
    '--- Query Network Information ---
    If Err.Number = 0 Then
        WScript.Echo strServer(k) &": Inventoring"
        Set colAdapters = objWMIService.ExecQuery("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")
            
        For Each objAdapter in colAdapters
            objWorksheet.Cells(x+1, y+2).Value = objAdapter.Description
            
            ' IP Address Logic
            If Not IsNull(objAdapter.IPAddress) Then
                For i = LBound(objAdapter.IPAddress) To UBound(objAdapter.IPAddress)
                    If Not InStr(objAdapter.IPAddress(i),":") > "0" Then
                        objWorksheet.Cells(x+1, y+3).Value = objAdapter.IPAddress(i)
                    End If
                Next
            End If
            ' Subnet Logic
            If Not IsNull(objAdapter.IPSubnet) Then
                For i = LBound(objAdapter.IPSubnet) To UBound(objAdapter.IPSubnet)
                    If objAdapter.IPSubnet(i)<> "64" Then
                        objWorksheet.Cells(x+1, y+4).Value = objAdapter.IPSubnet(i)
                    End If
                Next                     
            End If
            
            objWorksheet.Cells(x+1, y+5).Value = objAdapter.MACAddress
            ' Gateway Logic
            If IsNull(objAdapter.DefaultIPGateway) Then
                objWorksheet.Cells(x+1, y+6).Value = "Gateway Not Set"
            Else
                For i = LBound(objAdapter.DefaultIPGateway) To UBound(objAdapter.DefaultIPGateway)
                    objWorksheet.Cells(x+1, y+6).Value = objAdapter.DefaultIPGateway(i)
                Next
            End If 
            ' DNS Logic
            If IsNull(objAdapter.DNSServerSearchOrder) Then
                objworksheet.Cells(x+1, y+7).Value = "DNS Not Set" 
            Else
                For i = LBound(objAdapter.DNSServerSearchOrder) To UBound(objAdapter.DNSServerSearchOrder)
                    objWorksheet.Cells(x+1, y+7).Value = objAdapter.DNSServerSearchOrder(i)
                    y = y + 1
                Next
            End If
            y = 1
                  
            objWorksheet.Cells(x+1, y+12).Value = objAdapter.WINSPrimaryServer
            objWorksheet.Cells(x+1, y+13).Value = objAdapter.WINSSecondaryServer
            objWorksheet.Cells(x+1, y+14).Value = objAdapter.DNSDomain
            
            ' Suffix Logic
            If IsNull(objAdapter.DNSDomainSuffixSearchOrder) Then
                objworksheet.Cells(x+1, y+14).Value = "Suffix Order NA" 
            Else
                For i = LBound(objAdapter.DNSDomainSuffixSearchOrder) To UBound(objAdapter.DNSDomainSuffixSearchOrder)
                    objWorksheet.Cells(x+1, y+15).Value = objAdapter.DNSDomainSuffixSearchOrder(i)
                    x = x + 1
                Next
                x = x - 1
            End If
                  
            x = x + 1
            WScript.Echo strServer(k) &": Completed" 
        Next
    Else
        ' Error Handling for Offline Servers
        objWorksheet.Cells(x+1, y+16).Value = Err.Number & "_" & Err.Description 
        WScript.Echo strServer(k) &": "& Err.Description
        Err.Clear
        x = x + 1
    End If
    s = s + 1
Loop
'--- Formatting and Saving ---
Set objRange = objWorksheet.UsedRange
objRange.EntireColumn.Autofit()
objExcel.ActiveWorkbook.Saveas strOutput & "IP_Addresses.xlsx"
MsgBox "Operation Completed Successfully " ,,"IP Address"

Key Features of the Script

  • Automatic Excel Formatting: It uses UsedRange.Autofit() to ensure the data is readable as soon as the file opens.
  • WMI Integration: It queries the Win32_NetworkAdapterConfiguration class directly from the remote machine.
  • Multi-Adapter Support: If a server has multiple enabled NICs, the script loops through each to capture all configurations.
  • Remark Logging: If a machine is unreachable, the error code and description are written directly into the Excel “Remarks” column so you know which servers to check manually.

This entry was posted in Scripts and tagged , , , , , , , , , , , , , .

Fix: “Not enough server storage is available to process this command”

Posted on Updated on

Have you ever tried to access a network share or run a command only to be met with the cryptic error: “Not enough server storage is available to process this command”?

Despite what the message says, this almost never means you are out of disk space. Instead, it usually refers to a specific memory buffer in the Windows kernel called the IRPStackSize (I/O Request Packet Stack Size).

The Fix: Increasing the IRPStackSize

When too many filter drivers (antivirus, firewall, or backup tools) are installed, the default stack size isn’t deep enough to handle the requests. We can fix this by a quick trip to the Windows Registry.

Step-by-Step Instructions:

  1. Press Win + R, type regedit, and hit Enter.
  2. Navigate to the following path: HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\LanmanServer\Parameters
  3. Look for a value named IRPStackSize.
    • If it exists: Double-click it.
    • If it doesn’t exist: Right-click in the right pane, select New > DWORD (32-bit) Value.
    • CRITICAL: You must name it exactly IRPStackSize. The system is case-sensitive for this specific entry.
  4. Change the Base to Decimal.
  5. Set the Value data to 16 or higher.
    • The default is 15. If you are already at 15 and seeing the error, try increments of 3 (e.g., 18, 21, 24). The maximum value is 50.
  6. Click OK, close the Registry Editor, and restart your computer (or restart the “Server” service).

#WindowsServer #SysAdmin #TechFix #RegistryEditor #ITPro #ServerStorage #WindowsTips #LazyAdmin #Troubleshooting #SoftwareEngineering

This entry was posted in Windows and tagged , , , , , , , .